Урок 11. Программные таймеры в Ардуино. Циклы с различными временами периода от одного таймера.

Arduino UNO R3

Научимся создавать программные таймеры  в параллельных процессах. Напишем учебную программу для охранной сигнализации.

Предыдущий урок     Список уроков     Следующий урок

В предыдущем уроке на примере программы контроллера холодильника я говорил, что в реальных программах для микроконтроллеров приходится обрабатывать одновременно несколько задач в циклах с разными временами периодов.

 

Как создавать программные таймеры для таких циклов. В принципе, также как и аппаратные.

  • В системе циклически вызывается одно прерывание от аппаратного таймера. Время периода выбирается наименьшим среди требуемых программных таймеров.
  • В обработчике прерывания от таймера, в каждом цикле прибавляется 1 к счетчику программного таймера.
  • При достижении кодом счетчика заданного значения он сбрасывается в 0. Период программного таймера вычисляется, как  время периода прерывания аппаратного таймера умноженное на значение кода сброса счетчика.

Вот пример программы с тремя  программными таймерами на 10, 200 и 1000 мс.

#define CYCLE_1_TIME 5    // время цикла 1 ( * 2 = 10 мс)
#define CYCLE_2_TIME 100  // время цикла 2 ( * 2 = 200 мс)
#define CYCLE_3_TIME 500  // время цикла 3 ( * 2 = 1 сек)

byte  timerCount1;    // счетчик таймера 1
byte  timerCount2;    // счетчик таймера 2
boolean flagTimer2;   // признак программного таймера 2
unsigned int timerCount3; // счетчик таймера 3

void loop() {

  // программный таймер 1, период 10 мс
  // счетчик таймера контролируется в асинхронном цикле
  if ( timerCount1 >= CYCLE_1_TIME ) {
    timerCount1= 0;
    // код программы вызывается каждые 10 мс
  }

  // программный таймер 2, период 200 мс
  // счетчик таймера контролируется в обработчике прерывания
  if ( flagTimer2 == true ) {
    flagTimer2= false;
    // код программы вызывается каждые 200 мс   
  }

}

// обработчик прерывания 2 мс
void  timerInterupt() {

  timerCount1++;  // + 1 к счетчику таймера 1

  timerCount2++;  // + 1 к счетчику таймера 2
  if ( timerCount2 >= CYCLE_2_TIME ) {
    timerCount2= 0;     // сброс счетчика
    flagTimer2= true;   // установка флага таймера 2
  }

  // программный таймер 3, период 1000 мс
  // счетчик таймера контролируется в обработчике прерывания
  // выполняется также в цикле прерывания  
  timerCount3++;  // + 1 к счетчику таймера 3
  if ( timerCount3 >= CYCLE_3_TIME ) {
    timerCount3= 0;     // сброс счетчика
    // код программы вызывается каждые 1000 мс   
  } 
}

Для всех трех таймеров созданы свои счетчики. Ко всем счетчикам в обработчике прерывания каждые 2 мс прибавляется 1.

Счетчик таймера 1 проверяется в асинхронном цикле loop(). Когда его код достигает значения равного константе CYCLE_1_TIME, он сбрасывается и выполняется код программы для этого цикла.

Счетчик второго таймера проверяется в обработчике прерывания. При достижении кода сброса он сбрасывается и вырабатывается признак flagTimer2. Этот признак анализируется в асинхронном цикле и, при его активном состоянии выполняется код для цикла 2 с периодом 200 мс.

Разница у этих способов заключается в том, что при контроле счетчика в асинхронном цикле его состояние должно проверятся не реже времени периода прерывания. Если, к примеру, в асинхронном цикле программа задержится на 10 мс, то за это время счетчик timerCount1 насчитает лишние 5 единиц и будет сброшен при большем значении. Таким образом, время цикла нарушится. Во втором случае счетчик таймера 2 будет сброшен в обработчике прерывания вовремя. При задержке в асинхронном цикле задержится реакция на программный таймер 2, но период самого цикла не нарушится.

Счетчик третьего таймера контролируется в обработчике прерывания и там же выполняется код программы для этого таймера.

Могут быть разные варианты реализации циклов с разными периодами. Бывают еще программные таймеры синхронизированные друг от друга или от общего таймера.  Какой способ применять надо решать в конкретной задаче.

 

Программа для упрощенной охранной сигнализации.

Давайте напишем реальную программу для охранной сигнализации. Это упрощенный вариант моей разработки на PIC контроллере. В будущем мы доведем эту сигнализацию до полного аналога этой разработки на Ардуино, а затем усложним, добавив GSM управление и оповещение, увеличим число датчиков, исполнительных устройств.

К плате Ардуино подключены следующие компоненты сигнализации:

  • Датчик открывания двери. Имитируем его кнопкой 1, считаем, что в нормальном состоянии (дверь закрыта) датчик разомкнут, а при открытой двери – замкнут.
  • Светодиод состояния сигнализации, расположенный над входной дверью:
    • отключена – не светится;
    • включена (режим охрана) – мигает раз в секунду;
    • сработала (режим тревога) – мигает 4 раза в секунду.
  • Кнопка включения/отключения сигнализации. Скрытая кнопка у входной двери. Реально это может быть замаскированный геркон, коммутацию которого можно производить постоянным магнитом.
  • Сирена тревоги –  пьезоэлектрический излучатель.

Схема подключения этих элементов к плате Ардуино.

Схема подключения к плате Ардуино

У меня макет устройства выглядит так.

Макет охранной сигнализации на Ардуино

Алгоритм работы устройства.

  • При включении сигнализация отключена, светодиод состояния не светится.
  • Закрыв входную дверь, нажимаем скрытую кнопку (или прикасаемся магнитом к скрытому геркону). Сигнализация включается. О чем сигнализирует светодиод, мигая раз в секунду. В этом режиме сигнализация контролирует состояние датчика двери.
  • Перед тем как открыть дверь надо отключить сигнализацию нажатием скрытой кнопки.
  • Если дверь откроется при включенной сигнализации, устройство перейдет в режим тревоги. Начнет звучать сигнал сирены, и светодиод будет мигать с частотой 4 раза в секунду.
  • В этом состоянии устройство будет находиться в течение 30 секунд, а затем отключится. Можно отключить сигнал тревоги раньше нажатием кнопки.

Не знаю, насколько такая сигнализация может быть использована на практике, но для учебной программы вполне функциональная задача.

 

Последовательность разработки программы.

В программе много комментариев, все должно быть понятно. Я больше внимания уделю логической последовательности разработки программы.

  • Создаем объекты кнопка (Button):
    • doorSens – датчик двери;
    • secretButton – скрытая кнопка.
  • Создаем прерывание от таймера с периодом 2 мс.
  • Вызываем в прерывании методы фильтрации сигналов датчика двери и кнопки.
  • Назначаем выводы контроллера для всех компонентов.
  • Задаем режим выводов для светодиода и сирены.

// упрощенная охранная сигнализация

#include <MsTimer2.h>
#include <Button.h>

#define DOOR_SENS_PIN 12      // датчик двери подключен к выводу 12
#define SECRET_BUTTON_PIN 11  // скрытая кнопка подключена к выводу 11
#define LED_PIN 10            // светодиод подключен к выводу 10
#define SIREN_PIN 9           // сирена подключена к выводу 9

Button doorSens(DOOR_SENS_PIN, 50);  // создание объекта датчик двери, типа кнопка
Button secretButton(SECRET_BUTTON_PIN, 25); // создание объекта скрытая кнопка, типа кнопка
 
void setup() {
  pinMode(LED_PIN, OUTPUT);      // определяем вывод светодиода как выход
  pinMode(SIREN_PIN, OUTPUT);      // определяем вывод сирены как выход
  MsTimer2::set(2, timerInterupt); // задаем период прерывания по таймеру 2 мс
  MsTimer2::start();              // разрешаем прерывание по таймеру
}

void loop() {
// пока кода нет
}

// обработчик прерывания 2 мс
void  timerInterupt() {

  doorSens.filterAvarage();  // вызов метода фильтрации сигнала для датчика двери 
  secretButton.filterAvarage();  // вызов метода фильтрации сигнала для скрытой кнопки 

}

Теперь у нас в программе есть все компоненты системы. На этом этапе можно проверить аппаратную часть устройства. Для этого надо временно сделать в цикле loop() простую логическую связь между кнопками, светодиодом и сиреной. И убедится, что на открытие двери или нажатие кнопки реагирует светодиод. Мы так делали в предыдущих уроках.

Если не проверяем аппаратную часть, то, по крайней мере, компилируем программу для проверки на формальные ошибки.

Сирена у нас это пьезоэлектрический излучатель. Для того, чтобы он издавал звук тревоги надо сформировать на нем сигнал переменной формы. Сделаем программный блок для формирования этого сигнала. Будем просто инвертировать состояние соответствующего вывода в самом быстром цикле – обработчике прерывания. Для включения и выключения сирены создадим признак.

boolean sirenOn;  // признак включения сирены

В обработчике прерывания напишем:

// блок управления сиреной
  if ( sirenOn == true) digitalWrite(SIREN_PIN, ! digitalRead(SIREN_PIN));

Для проверки можно вставить в loop()

sirenOn= secretButton.flagPress;  // проверка сирены

При нажатии скрытой кнопки сирена (пьезоизлучатель) будет издавать тревожный сигнал. Не забудьте удалить после проверки.

 

Структура программы.

Задумываемся о структуре и режимах программы. Самая простая и логичная структура следующая. В асинхронном цикле выделены блоки – режимы. В каждом блоке программа работает по циклу, а на другие блоки (режимы) переходит при определенных условиях с помощью оператора goto. Логически можно выделить следующие режимы работы устройства:

  • сигнализация отключена (ОТКЛЮЧЕНА);
  • сигнализация включена (ОХРАНА);
  • сигнализация сработала (ТРЕВОГА).

Давайте создадим такие программные блоки, каждый с бесконечным циклом и меткой вначале для перехода.

void loop() {

//---------------------- режим ОТКЛЮЧЕНА --------------------------
guard_off:
  while (true)  {
                
  }

//---------------------- режим ОХРАНА --------------------------------
guard_on:
  while (true)  {
   
  }

//---------------------- режим ТРЕВОГА --------------------------------
alarm:
  while (true)  {
   
  }           
}

Считается, что применение оператора goto надо ограничивать. Но в случаях, когда этот оператор упрощает понимание логики программы, облегчает ее читаемость, применение goto признано оправданным. У нас как раз тот случай. Ведь по логике может быть переход в любой блок из любого. Операторами break, continue и т.п. такие переходы не обеспечить.

Заполняем кодом каждый блок-режим.

Для блока ОТКЛЮЧЕНА:

  • светодиод не горит;
  • сирена не звучит;
  • если нажали кнопку, то переход на режим ОХРАНА.

//---------------------- режим ОТКЛЮЧЕНА --------------------------------
guard_off:
  while (true)  {

    digitalWrite(LED_PIN, LOW); // светодиод не горит
    sirenOn= false;           // сирена не звучит

    // если нажали кнопку, переход на режим ОХРАНА
    if ( secretButton.flagClick == true ) {
      secretButton.flagClick= false;
      goto  guard_on;     
    }   
  }

Можно попробовать загрузить в плату. Светодиод не светится, сирена не звучит.

Для блока ОХРАНА:

  • светодиод мигает раз в секунду;
  • сирена не звучит;
  • если нажали кнопку, то переход на режим ОТКЛЮЧЕНА;
  • если сработал датчик двери, то переход на режим ТРЕВОГА.

Чтобы реализовать мигание светодиода объявляем счетчик времени ledTimeCount и две константы: TIME_LED_PERIOD и TIME_LED_ON. Первая задает период мигания светодиода (500 для 1 секунды), вторая  время включенного состояния (100 для 0,2 сек). Счетчик времени увеличиваем на 1 в каждые 2 мс в обработчике прерывания, а светодиодом управляем простой логикой в блоке режима ОХРАНА.

#define TIME_LED_PERIOD 500   // время периода мигания светодиода (* 2 мс)
#define TIME_LED_ON 100       // время включенного светодиода

unsigned int ledTimeCount; // счетчик времени для светодиода

//---------------------- режим ОХРАНА --------------------------------
guard_on:
  while (true)  {

    sirenOn= false;   // сирена не звучит
    alarmTimeCount= 0;  // сброс счетчика времени тревоги     
   
    // светодиод мигает раз в секунду
    if ( ledTimeCount >= TIME_LED_PERIOD )  ledTimeCount= 0;
    if ( ledTimeCount < TIME_LED_ON )  digitalWrite(LED_PIN, HIGH);
    else digitalWrite(LED_PIN, LOW);

    // если нажали кнопку, переход на режим ОТКЛЮЧЕНА
    if ( secretButton.flagClick == true ) {
      secretButton.flagClick= false;
      goto  guard_off;     
    }   
   
    // если сработал датчик двери, переход на режим ТРЕВОГА
    if ( doorSens.flagPress == true ) goto  alarm;
   
  }

//------------------- обработчик прерывания 2 мс ---------------------
void  timerInterupt() {

// ………….

 ledTimeCount++;  // счетчик времени мигания светодиода   
}

Загружаем в плату Ардуино. Проверяем, что нажатие кнопки переводит устройство в режим ОХРАНА (мигает светодиод). Следующее нажатие кнопки возвращает в режим ОТКЛЮЧЕНА (светодиод погашен).

Остается заполнить блок режима ТРЕВОГА:

  • светодиод мигает 4 раза в секунду;
  • звучит сирена;
  • если нажали кнопку, то переход на режим ОТКЛЮЧЕНА;
  • если прошло 30 секунд – переход на режим ОТКЛЮЧЕНА.

Добавляем константу TIME_LED_ALARM - время периода мигания светодиода при ТРЕВОГЕ. Используем тот же счетчик для светодиода.

Для отсчета времени в режиме тревоги объявляем счетчик alarmTimeCount и константу TIME_ALARM - время в режиме ТРЕВОГА (30 сек). Перед входом в режим ТРЕВОГА счетчик должен быть сброшен.

Все. Программа готова. Итоговый скетч:

// упрощенная охранная сигнализация

#include <MsTimer2.h>
#include <Button.h>

#define DOOR_SENS_PIN 12      // датчик двери подключен к выводу 12
#define SECRET_BUTTON_PIN 11  // скрытая кнопка подключена к выводу 11
#define LED_PIN 10            // светодиод подключен к выводу 10
#define SIREN_PIN 9           // сирена подключена к выводу 9

#define TIME_LED_PERIOD 500   // время периода мигания светодиода (* 2 мс)
#define TIME_LED_ON 100       // время включенного светодиода
#define TIME_LED_ALARM 62   // время периода мигания светодиода при ТРЕВОГЕ (* 2 мс)
#define TIME_ALARM 15000   // время в режиме ТРЕВОГА (* 2 мс)
  
Button doorSens(DOOR_SENS_PIN, 50);  // создание объекта датчик двери, типа кнопка
Button secretButton(SECRET_BUTTON_PIN, 25); // создание объекта скрытая кнопка, типа кнопка

boolean sirenOn;  // признак включения сирены
unsigned int ledTimeCount; // счетчик времени для светодиода
unsigned int alarmTimeCount; // счетчик времени тревоги
 
void setup() {
  pinMode(LED_PIN, OUTPUT);      // определяем вывод светодиода как выход
  pinMode(SIREN_PIN, OUTPUT);      // определяем вывод сирены как выход
  MsTimer2::set(2, timerInterupt); // задаем период прерывания по таймеру 2 мс
  MsTimer2::start();              // разрешаем прерывание по таймеру
}

void loop() {

//---------------------- режим ОТКЛЮЧЕНА --------------------------
guard_off:
  while (true)  {

    digitalWrite(LED_PIN, LOW); // светодиод не горит
    sirenOn= false;           // сирена не звучит

    // если нажали кнопку, переход на режим ОХРАНА
    if ( secretButton.flagClick == true ) {
      secretButton.flagClick= false;
      goto  guard_on;     
    }   
  }

//---------------------- режим ОХРАНА --------------------------------
guard_on:
  while (true)  {

    sirenOn= false;   // сирена не звучит
    alarmTimeCount= 0;  // сброс счетчика времени тревоги     
   
    // светодиод мигает раз в секунду
    if ( ledTimeCount >= TIME_LED_PERIOD )  ledTimeCount= 0;
    if ( ledTimeCount < TIME_LED_ON )  digitalWrite(LED_PIN, HIGH);
    else digitalWrite(LED_PIN, LOW);

    // если нажали кнопку, переход на режим ОТКЛЮЧЕНА
    if ( secretButton.flagClick == true ) {
      secretButton.flagClick= false;
      goto  guard_off;     
    }   
   
    // если сработал датчик двери, переход на режим ТРЕВОГА
    if ( doorSens.flagPress == true ) goto  alarm;
   
  }

//---------------------- режим ТРЕВОГА --------------------------------
alarm:
  while (true)  {

    sirenOn= true;   // звучит сирена

    // светодиод мигает 4 раза в секунду
    if ( ledTimeCount >= TIME_LED_ALARM ) {
      ledTimeCount= 0;
      digitalWrite(LED_PIN, ! digitalRead(LED_PIN));
    }

    // если нажали кнопку, переход на режим ОТКЛЮЧЕНА
    if ( secretButton.flagClick == true ) {
      secretButton.flagClick= false;
      goto  guard_off;     
    }   

    // проверка времени тревоги ( 30 сек )
    if ( alarmTimeCount >= TIME_ALARM ) goto  guard_off;
   
  }           
}

//------------------- обработчик прерывания 2 мс ---------------------
void  timerInterupt() {

  doorSens.filterAvarage();  // вызов метода фильтрации сигнала для датчика двери 
  secretButton.filterAvarage();  // вызов метода фильтрации сигнала для скрытой кнопки 

  // блок управления сиреной
  if ( sirenOn == true) digitalWrite(SIREN_PIN, ! digitalRead(SIREN_PIN));

 ledTimeCount++;  // счетчик времени мигания светодиода 
 alarmTimeCount++;  // счетчик времени тревоги
 
}

Скетч программы с расширением .ino можно загрузить по этой ссылке.

Загружаем в плату, проверяем. Открывание двери имитируем нажатием первой кнопки. Все работает.

Чтобы устройство могло работать в реальных условиях, желательно доработать электрическую схему, как это сделано по этой ссылке. Но лучше подождите, через несколько уроков напишем программу, полностью выполняющую функции прототипа. А позже добавим GSM оповещение и телемеханику.

 

Следующий урок будет посвящен передаче данных по последовательному интерфейсу UART и отладке программ на Ардуино.

Предыдущий урок     Список уроков     Следующий урок

25 комментариев на «Урок 11. Программные таймеры в Ардуино. Циклы с различными временами периода от одного таймера.»

  1. Эдуард, приветствую,
    Я сделал «учебную» сигнализацию по материалам вашего урока. Но т.к. я стараюсь не просто повторять код методом вставки, а писать самостоятельно, как запомнил задачу, а потом сверяться с вашей реализацией и проправлять свою, то окончательному результату предшестувует отладка. И здесь во время этой отладки я налетел на неприятный глюк. Я начал с того, что попытался, используя ранее написанный класс «кнопка» сделать два блока-режима «online» и «offline», где, условно, если девайс в онлайне, то светодиод горит, а если в оффлайне — не горит. Далее решил усложнять по мере отладки.
    Ранее написанная программа включения-выключения светодиода с классом-библиотекой работала прекрасно, а вот после разбиения на функциональные модули с «вечными» циклами в каждом, конструкция работать прекратила. Блоки выглядели так:
    //————begin code-fragment———
    offline:
    while(true) {
    if (button1.flagClick == HIGH) {
    ledState=HIGH;
    digitalWrite(LED_PIN,ledState);
    button1.flagClick=LOW;
    goto online;
    }
    }

    online:
    while(true) {
    if (button1.flagClick == HIGH) {
    ledState=LOW;
    digitalWrite(LED_PIN,ledState);
    button1.flagClick=LOW;
    goto offline;
    }
    }
    //—————end code-fragment————
    Обработчик прерывания по таймеру исправно отрабатывал, флаг нажатия выставлялся, но почему-то не отлавливался в основной программе.
    Я грешил на код основной программы, затем на класс, также хоть и по вашей указке, но написанный самостоятельно. После этого скачал вашу библиотеку, попробовал с ней — то же самое. После этого скачал и запустил ваш код сигнализации, который заработал и с моим и с вашим классом. В итоге выяснилось, что если вставить перед проверкой флага нажатия хотя бы один оператор, неважно какой — я пробовал delay, Serial.print или прописывать дополнительно состояние светодиода, то и мой код тоже начинает работать. Т.е. вот версия, которая работает:
    //—————begin code-fragment———————-

    offline:
    while(true) {
    delay(1); //если вместо этого поставить строку ниже, а эту убрать, то тоже будет работать
    //digitalWrite(LED_PIN,LOW);
    if (button1.flagClick == HIGH) {
    ledState=HIGH;
    digitalWrite(LED_PIN,ledState);
    button1.flagClick=LOW;
    goto online;
    }
    }

    online:
    while(true) {
    delay(1);
    //digitalWrite(LED_PIN,HIGH);
    if (button1.flagClick == HIGH) {
    ledState=LOW;
    digitalWrite(LED_PIN,ledState);
    button1.flagClick=LOW;
    goto offline;
    }
    }

    //——————end code-fragment——————

    В коде сигнализации до проверки условия нажатия тоже присутствуют какие-то действия, поэтому там такой проблемы, как была у меня изначально — нет.
    Я попробовал воспроизвести эту ситуацию на двух версиях плат — Micro и Mega2560. Поведение было одинаковым. Вы случайно ни на что подобное не наступали? Как можно отловить причину такого поведения?

    Прошу прощения за много букв, если сочтете лишним, не публикуйте этот коментарий, а ответьте лично в почту.

    Спасибо,
    Денис.

    • Денис, здравствуйте!
      Я столкнулся с подобным эффектом, который объяснить не смог.
      В прерывании по таймеру у меня взводился флаг, а в бесконечном цикле while() он анализировался. Программа никак на него не реагировала. Я убрал все классы, оставил самые примитивные операции, но результат остался прежним.
      Далее я выяснил, что программа правильно реагировала на признак из обработчика прерывания только при выполнении цикла loop() до конца. Очевидно, что при каждом цикле loop происходит какая-то перегрузка переменных или что-то подобное. Интересно, что программ правильно работала с бесконечным циклом while() если в нем присутствовала любая системная функция, например digitalWrite(), delay(), да любая. Даже на разрешение прерывания interrupts(), проще и короче функции нет. Скорее всего, при вызове системных функций тоже происходит перегрузка переменных.
      Советую поступить так. В принципе, использовать циклы wile() для ожидания не хорошо. Я применил их в одном из начальных уроков, чтобы было проще объяснять алгоритм программы. В реальных программах я так никогда не делаю. Правильнее структуру программы строить по принципу из урока 17.
      if ( mode == 0 ) {
      // СИГНАЛИЗАЦИЯ ОТКЛЮЧЕНА
      }
      else if ( mode == 1 ) {
      // УСТАНОВКА НА СИГНАЛИЗАЦИЮ
      }
      else if ( mode == 2 ) {
      // ОХРАНА
      }
      else if ( mode == 3 ) {
      // БЛОКИРОВКА
      }
      else mode= 0;
      В этом случае цикл loop() не задерживается, всегда выполняется. В нем также могут находиться общие для любого режима действия.
      Рад, что Вы затронули эту тему. Если не согласны напишите.

      • Добрый.
        Это не баг, небольшой пробел в знаниях.
        Вы неявно изменяете переменную, почитайте про квалификатор типов volatile.

        • Спасибо! К своему стыду вынужден согласиться. Надо перед переменной поставить квалификатор volatile. Тогда компилятор отключит оптимизацию операций с этой переменной и будет ее проверять при каждом проходе цикла.
          В уроке 10 есть подробное описание volatile.

          • Вам спасибо, я давно уже не программист, и вот ваши готовые куски кода очень кстати.

  2. Эдуард,
    Да, я конечно соглашусь, что while (true) {} использовать не следует. Просто этот «баг» отнял довольно много времени, что неприятно. Но радует, что не у меня одного ))
    В общем, продолжаю в свободное время с удовольствием изучать ваши уроки, а также пытаюсь перенести принципы борьбы с дребезгом, описанные у вас здесь, на платформу ARM STM32. Еще раз большое спасибо, что описали эффективный алгоритм.

  3. Здравствуйте, Эдуард.

    Начал изучать ваши уроки. Очень методичные, структурные, то что надо. В этой программе обнаружил ошибку. При выходе программы в режим тревога зуммер не прекращает работу после нажатия на секретную кнопку а также спустя 30 сек.
    В timerInterupt после if вставил такую строку:
    else digitalWrite(SIREN_PIN,LOW);
    Все стало в норме.

    • Андрей, здравствуйте!
      В программе ошибки нет. Вы, наверное, использовали активную сирену. Т.е. напряжение на сирене есть — она верещит, напряжение сняли — молчит.
      А я использовал пассивный пьезоизлучатель, который пищит если на нем присутствует переменное напряжение частотой 0,5 — 2 кГц. Признак sirenOn не верен, значит сигнал на пьезоизлучателе не меняется, и он молчит.
      А в применении к активной сирене Вы абсолютно правы. Ее надо выключать. Ее надо и включать потенциалом. Тогда в прерывании ничего с сиреной делать не надо. Просто управлять ей из основного цикла.

      • Да, Эдуард.

        Спасибо за ответ. Видимо так и есть у меня по рукой оказалась только активная сирена ТМВ12А05.
        Все остальное пока понятно, буду двигаться дальше по Вашим урокам.

  4. Эдуард, доброго дня!

    Собрал по вашему примеру макетку, но вместо пищалки на 9 пин включен светодиод. Из режима тревоги диод этот нормально гаснет по нажатию кнопки secretbutton, но почему-то он не гаснет через 30 секунд. Почему так может быть?

    • Здравствуйте! Кирилл, почитайте мой ответ на вопрос Андрея в комментариях к этому уроку. У Вас та же проблема. Я использовал пассивный пьезоизлучатель. Для выключения звука программа перестает формировать звуковую частоту на нем, т.е. перестает изменять уровень сигнала. Если сигнал на выводе остался при выключении звука в высоком уровне, то будет светится светодиод.

  5. Здравствуйте, Эдуард.
    загрузил: «Скетч программы с расширением .ino можно загрузить по этой ссылке.» Выдало ошибку при проверке
    error: ‘timerInterupt’ was not declared in this scope
    Библиотеки подключил, чего то не хватает?

    • Здравствуйте! Возможно, у Вас скетч расположен в папке названной русскими буквами. Проверьте. Названия всех каталогов пути до скетча должно содержать только латинские символы.

  6. ЗДРАВСТВУЙТЕ ПОДСКАЖИТЕ КАК НАПИСАТЬ ЭТУ ЛОГИКУ.

    12 ПИН ЛОВ.
    ЕСЛИ НА 11 ПИНЕ (ЛОВ ИЛИ ХАЙ ТЕЧЕНИИ 2 МИНУТ) ТО
    12 ПИН ЛОВ
    ИНАЧИ
    12ПИН ХАЙ .

  7. Здравствуйте, Эдуард! В данном уроке мне непонятен один момент:

    // если сработал датчик двери, переход на режим ТРЕВОГА
    if ( doorSens.flagPress == true ) goto alarm;

    Почему на режим ТРЕВОГА программа переходит по признаку flagPress, а не flag.Click?

    • Здравствуйте!
      Можно и так. Разницы особой нет. Где это возможно я предпочитаю анализировать текущее состояние, а не детектор фронта.

      • Извините, Эдуард, я правда много думал, прежде, чем спросить! Но зачем нам тогда вообще переменная flagClick?

        • flagPress показывает текущее состояние кнопки. Кнопку нажали flagPress стала равной true. Кнопку отжали flagPress стала равной false.

          flagClick показывает было ли нажатие, перешла ли кнопка из состояния отжата в состояние нажата. Эта переменная реагирует на перепад состояния кнопки. Нажали кнопку — flagClick стала равной true. А сброс этой переменной надо производить в программе после обработки события.

          Представьте, что вам надо на каждое нажатие кнопки инвертировать состояние светодиода. Как вы это будете делать с помощью flagPress.

  8. Спасибо. Все круто.
    Но я бы заменил:
    <>
    на
    <>
    через 30 сек. не вырубается. Думаю нужно втащить здесь автомат состояний.

    • Код не отобразился.
      Кароче, добавил команду на затыкание сирены и чуть изменил ваш код, добавив автомат состояний.
      Бесконечные циклы и ненавистные GOTO убрал.
      Не сочтите за нескромность.

      void loop() {

      switch (sost){
      case 0:{

      //———————- режим ОТКЛЮЧЕНА ———————————
      //guard_off:
      //while (true) {

      digitalWrite(LED_PIN, LOW); // светодиод не горит
      sirenOn= false; // сирена не звучит
      digitalWrite(SIREN_PIN, LOW); // сирена не звучит

      // если нажали кнопку, переход на режим ОХРАНА
      if ( secretButton.flagClick == true ) {
      secretButton.flagClick= false;
      //goto guard_on;
      sost = 1;
      }
      //}
      }//case 0:{
      break;

      case 1:{

      //———————- режим ОХРАНА ———————————
      //guard_on:
      //while (true) {

      sirenOn= false; // сирена не звучит
      alarmTimeCount= 0; // сброс счетчика времени тревоги

      // светодиод мигает раз в секунду
      if ( ledTimeCount >= TIME_LED_PERIOD ) ledTimeCount= 0;
      if ( ledTimeCount = TIME_LED_ALARM ) {
      ledTimeCount= 0;
      digitalWrite(LED_PIN, ! digitalRead(LED_PIN));
      }

      // если нажали кнопку, переход на режим ОТКЛЮЧЕНА
      if ( secretButton.flagClick == true ) {
      secretButton.flagClick= false;
      //goto guard_off;
      sost = 0;
      }

      // проверка времени тревоги ( 30 сек )
      if ( alarmTimeCount >= TIME_ALARM ) {
      //goto guard_off;
      sost = 0;
      }

      //}
      }//case -1:{
      break;
      }
      }

      • Ну и конечно для этого нужно объявить переменную, и в setup ей назначить значение по умолчанию.

        int sost = 0;//3 состояния
        // 0 = guard_off:
        // 1 = guard_on:
        // -1 = alarm: !!!

        void setup() {
        pinMode(LED_PIN, OUTPUT); // определяем вывод светодиода как выход
        pinMode(SIREN_PIN, OUTPUT); // определяем вывод сирены как выход
        MsTimer2::set(2, timerInterupt); // задаем период прерывания по таймеру 2 мс
        MsTimer2::start(); // разрешаем прерывание по таймеру

        sost = 0;// на всякий
        }

        Остальное не менял

      • Так, конечно, правильнее. Но это учебная программа, в уроках единственная с goto.

Добавить комментарий

Ваш e-mail не будет опубликован. Обязательные поля помечены *