Рассмотрим функции работы со временем. Разработаем спортивный секундомер на базе платы Ардуино.
Предыдущий урок Список уроков Следующий урок
Для работы со временем в системе Ардуино существуют 4 стандартные функции:
- delay(time);
- delayMicroseconds(time);
- millis();
- micros().
Рассмотрим эти функции подробно.
void delay(unsigned long time)
Функция приостанавливает работу программы на время time, заданное в мс.
delay(500); // пауза на 0,5 сек
Мы уже использовали эту функцию в предыдущих уроках. Использовали в отладочных программах. В практических программах функция применяется редко.
Дело в том, что она останавливает работу программы. Программа ничего не делает в течение заданного отрезка времени. Не позволительная роскошь, допустимая только в отладочных режимах.
Кроме того, функция не позволяет создавать циклы с заданным временем. Например, время следующего цикла не будет точно равно 100 мс.
while(true) {
// код программного блока
delay(100);
}
Время цикла равно сумме: времени 100 мс, времени выполнения программного блока и времени перехода на начало цикла while(). Время программного блока может меняться в зависимости от алгоритма выполнения программы. Время перехода на начало цикла тоже не определено точно. В результате время цикла можно определить только приблизительно.
Для организации циклов с заданным временем лучше использовать прерывание по таймеру (урок 10). Надо только понимать, что такой способ обеспечивает стабильное время цикла, но оно может несколько отличаться от заданного. Например, библиотека MsTimer2 задает время в мс. Реальное время может отличаться на 1-2 мкс. В некоторых приложениях, например в часах, ошибка будет накапливаться и приведет к недопустимой погрешности.
void delayMicroseconds(int time)
Функция приостанавливает работу программы на время time, заданное в мкс.
delayMicroseconds(50); // пауза на 50 мкс
Аналог функции delay(), только обеспечивает более короткие остановки программы. Вполне допустима для использования в практических программах по двум причинам.
- Короткие отрезки времени сложно реализовать другими методами.
- Остановка программы даже на несколько десятков микросекунд не вызовет катастрофических последствий.
unsigned long millis(void)
Функция возвращает время в мс, с момента запуска текущей программы. Значение времени переполняется через 1193 часов, приблизительно 50 суток.
tm = millis(); // чтение времени в tm
По сути это функция чтения системного времени Ардуино. Время считается в параллельном процессе и не зависит от алгоритмов выполнения программы, остановок, в том числе и функцией delay(), и т.п. Для измерения интервалов времени необходимо считать системное время в начале и конце интервала и выполнить разность этих значений. Ниже будет пример программы для работы с временными интервалами.
Запрещение прерываний функцией noInterrupts() на длительное время может нарушить работу системных часов.
Точность работы функции millis().
Точность отсчета времени функцией millis() определяется точностью и стабильностью частоты кварцевого резонатора платы Ардуино. Даже для дешевых резонаторов погрешность частоты не превышает 30 ppm. Вместе с температурной нестабильностью, в нормальных условиях, это 50 ppm, что соответствует ± 0,00005 %. Таким образом, суммарная абсолютная ошибка системного времени Ардуино составит:
- 0,18 сек для 1 часа;
- 4,32 сек для суток;
- 129,6 сек для месяца;
- 26 минут для года.
Наверное, вполне допустимая точность для создания секундомеров и даже часов.
unsigned long micros(void)
Функция возвращает время в мкс, с момента запуска текущей программы. Значение переполняется приблизительно через 70 минут.
tm = micros(); // чтение времени в tm
На платах Ардуино с частотой тактирования 16 мГц разрешение значения функции micros() составляет 4 мкс. Для плат с частотой 8 мГц – 8 мкс.
Спортивный секундомер на базе платы Ардуино.
Реализуем достаточно простой проект – секундомер. Наверное, практическое применение такого устройства ограничено. Секундомер с питанием от сети имеет право на существование только в стационарных устройствах. В табло для спортивных соревнований, в системах для интеллектуальных игр, и т.п. Но разобравшись в программе, Вы легко сможете подкорректировать секундомер под свои задачи или создать совершенно другое устройство.
Управление секундомером осуществляется двумя кнопками:
- ПУСК/СТОП;
- СБРОС.
После нажатия на кнопку ПУСК/СТОП секундомер начинает отсчитывать время. Повторное нажатие на эту кнопку останавливает счет. Следующее нажатие продолжает отсчет времени с остановленного значения. Таким образом, секундомер может быть использован для отсчета ”чистого ” времени спортивных соревнований.
Для сброса значения времени необходимо нажать кнопку СБРОС.
Время отображается на четырех разрядном семисегментном индикаторе в следующих форматах.
| Значение времени | Разряд 3 | Разряд 2 | Разряд 1 | Разряд 0 |
| 0 … 59 сек | секунды | сотые доли секунды | ||
| 1 … 10 минут | минуты | секунды | десятые доли секунды | |
| 10 … 99 минут | минуты | секунды | ||
| Больше 99 минут | - | - | - | - |
Формат вывода данных меняется автоматически в зависимости от значения времени. Минуты, секунды и дробная часть отделяются на индикаторе децимальными точками. Нажатия на кнопки сопровождаются звуковыми сигналами.
Схема спортивного секундомера на базе платы Arduino UNO R3.
По уже хорошо известным нам схемам подключаем к плате Ардуино:
- 4х разрядный семисегментный светодиодный индикатор GNQ-3641BUE;
- две кнопки;
- звуковой пьезоизлучатель.
Все эти компоненты могут быть другими. Если Вы разрабатываете секундомер для спортивного табло, то индикаторы должны быть большими. Можете их собрать даже из отдельных светодиодов. Как подключить индикаторы к плате можно посмотреть в уроке 19.
Если кнопки управления секундомером физически расположены на значительном расстоянии от платы, то лучше их подключить по схеме из охранной сигнализации, урок 17. Или хотя бы соединить входы кнопок с питанием + 5 В через резисторы 1 кОм.
Но для отладки и проверки программы достаточно приведенной схемы. Я собрал ее на макетной плате.
Программа для спортивного секундомера на Ардуино.
Скетч программы можно загрузить по этой ссылке загрузить . Не забудьте установить библиотеки из предыдущих уроков: MsTimer2.h (урок 10), Led4Digits.h (урок 20) и Button.h (урок 9).
Скетч программы для секундомера выглядит так.
// спортивный секундомер
#include <MsTimer2.h>
#include <Led4Digits.h>
#include <Button.h>
#define SOUND_PIN 18 // звуковой излучатель, вывод 18 (A4)
// тип индикатора 1; выводы разрядов 5,4,3,2; выводы сегментов 6,7,8,9,10,11,12,13
Led4Digits disp(1, 5,4,3,2, 6,7,8,9,10,11,12,13);
Button buttonReset(16, 10); // кнопка СБРОС, вывод 16 (A2)
Button buttonStartStop(17, 10); // кнопка ПУСК/СТОП, вывод 17 (A3)
byte mode= 0; // режим, 0 - СТОП, 1 - ПУСК
unsigned long msTime=0; // время интервала, милисекунды
byte minTime=0; // время интервала, минуты
byte decMinTime=0; // время интервала, десятки минуты
unsigned long prevTime; // предыдущее значение времени
unsigned long curentTime; // текущее значение времени
byte soundCount=0; // счетчик времени звука
void setup() {
MsTimer2::set(2, timerInterrupt); // прерывания по таймеру 2 мс
MsTimer2::start(); // разрешение прерывания
pinMode(SOUND_PIN, OUTPUT); // вывод звукового излучателя
}
void loop() {
//----------------------- переключение режима СТАРТ/СТОП
if ( buttonStartStop.flagClick == true ) {
buttonStartStop.flagClick= false; // сброс признака
// инверсия режима
if ( mode == 0) {
mode= 1; // СТАРТ
soundCount= 250; // звук на старт 250*2 мс
}
else { // СТОП
mode= 0;
soundCount= 50; // звук на стоп 50*2 мс
}
}
//----------------------- кнопка СБРОС
if ( buttonReset.flagClick == true ) {
buttonReset.flagClick= false; // сброс признака
msTime=0;
minTime=0;
decMinTime=0;
soundCount= 50; // звук на сброс 50*2 мс
}
//----------------------- отсчет времени
if ( mode == 0 ) {
// СТОП
prevTime= millis();
}
else {
// ПУСК
curentTime= millis(); // чтение текущего времени
msTime += curentTime - prevTime; // прибавление времени к милисекундам
if ( msTime > 59999 ) {
// милисекунды переполнились, больше минуты
msTime -= 60000;
minTime ++; // +1 к единицам минут
if ( minTime > 9 ) {
// единицы минут переполнились
minTime -= 10;
decMinTime ++; // +1 к десяткам минут
}
}
prevTime= curentTime; // перегрузка предыдущего времени
}
//--------------------- отображение времени
if ( (minTime == 0) && (decMinTime == 0)) {
// меньше минуты
disp.print(msTime / 10, 4, 0); // вывод четырех разрядов милисекунд
// точки
disp.digit[0] &= 0x7f; // погасить
disp.digit[1] &= 0x7f; // погасить
disp.digit[2] |= 0x80; // зажечь
disp.digit[3] &= 0x7f; // погасить
}
else if ( decMinTime == 0 ) {
// меньше 10 минут
disp.print(msTime / 100, 3, 0); // вывод трех разрядов милисекунд
disp.tetradToSegCod(3, minTime); // в старший разряд вывод единиц минут
// точки
disp.digit[0] &= 0x7f; // погасить
disp.digit[1] |= 0x80; // зажечь
disp.digit[2] &= 0x7f; // погасить
disp.digit[3] |= 0x80; // зажечь
}
else if ( decMinTime < 10 ) {
// меньше 100 минут
disp.print(msTime / 1000, 2, 0); // вывод двух разрядов милисекунд
disp.tetradToSegCod(3, decMinTime); // в старший разряд вывод десятков минут
disp.tetradToSegCod(2, minTime); // в 3 разряд вывод единиц минут
// точки
disp.digit[0] &= 0x7f; // погасить
disp.digit[1] &= 0x7f; // погасить
disp.digit[2] |= 0x80; // зажечь
disp.digit[3] &= 0x7f; // погасить
}
else {
// больше 100 минут
// ----
disp.digit[0]= 0x40;
disp.digit[1]= 0x40;
disp.digit[2]= 0x40;
disp.digit[3]= 0x40;
}
}
//----------- обработчик прерывания 2 мс
void timerInterrupt() {
disp.regen(); // регенерация индикатора
buttonReset.filterAvarage(); // сканирование кнопки, метода фильтрации по среднему
buttonStartStop.filterAvarage(); // сканирование кнопки, метода фильтрации по среднему
// звук
if (soundCount != 0) {
digitalWrite(SOUND_PIN, ! digitalRead(SOUND_PIN));
soundCount--;
}
}
Большая часть программы разработана по принципам, подробно описанным в предыдущих уроках.
- Реализовано прерывание по таймеру с периодом 2 мс.
- В обработчике прерывания вызываются:
- метод регенерации индикатора;
- методы сканирования сигналов кнопок;
- блок формирования звукового сигнала.
- По признакам нажатия кнопок происходит:
- переключение режима (СТАРТ/СТОП);
- сброс показаний времени.
- В зависимости от значения времени в блоке отображения меняется формат вывода данных на индикатор.
Подробно хочется остановиться на программном блоке “отсчет времени”. Счет времени можно реализовать разными способами. Например, можно считать время в миллисекундах, а в блоке отображения делать перевод в нужный формат. Я решил, что намного проще считать время в формате:
- миллисекунды;
- минуты;
- десятки минут.
В этом случае не приходится выполнять двоично-десятичные преобразования для отображения минут. Конечно, если бы у нас была задача измерения одного интервала времени, то достаточно было бы считать время функцией millis() в начале и конце интервала, а затем вычислить разность. Но нам необходимо накопление времени, поэтому алгоритм несколько усложняется.
В программе достаточно комментариев. Думаю, Вы без труда разберетесь в ней и сможете создать устройство под свои задачи, будь это спортивный секундомер, система для интеллектуальных игр ”Что? Где? Когда?” или ”Брейн ринг” и многое другое. Мы вернемся к секундомеру и работе со временем при разработке спортивных табло на базе светодиодных модулей. Надеюсь, уже этим летом.
Предыдущий урок Список уроков Следующий урок
Автор публикации
Доброго времени, подскажите пожалуйста, Как изменить программу что бы секундомер работал при удержании кнопки? А при отпускании останавливался?
Здравствуйте. Я могу сходу ошибиться, но попробуйте изменить блок «переключение режима СТАРТ/СТОП» на простой алгоритм: если кнопка нажата, то режим ПУСК (mode=1), если кнопка отжата — СТОП (mode=0).
if ( buttonStartStop.flagPress == true ) mode=1;
else mode=0;
Спасибо, попробую
получилось но секунды слишком длинные=)
Что значит длинные? Не правильно время показывает?
в 2 раза замедлился ход
я не разбираюсь но помоему так как кнопка при работе всегда нажата ее же опрашивает программа — вот и вылазит погрешность — точнее не то что опрашивает а то что при каждом цикле обрабатывает условие
Нет. Вы все правильно сделали? Там независимый программный блок, который вырабатывает единственный признак mode и счетчик звука. Все должно работать. Я подумаю. Можете проверить поставить просто mode=1; И посмотреть как идет время.
//———————— переключение режима СТАРТ/СТОП
if ( buttonStartStop.flagPress == true ) {
buttonStartStop.flagClick= false; // сброс признака
// инверсия режима
if ( mode == 0) {
mode= 1; // СТАРТ
}
else { // СТОП
mode= 0;
}
}
//———————— кнопка СБРОС
вот эта часть
Да, этот блок.
ну уже измененный=)
и вот при постоянном удерживании кнопки в два раза медленнее работает секундомер=)
мне просто нужно управлять им с помощью реле — то есть при появлении 24вольт на определенном разъеме
Нет Вы не поняли. Надо весь блок заменить на
if ( buttonStartStop.flagPress == true ) mode=1;
else mode=0;
Раньше по нажатию кнопки инвертировался режим mode. А Вам надо если кнопка нажата, то mode=1, отжата mode=0
по всякому пробывал…..не откомпилировать — ошибки, я в синтаксисе не особо понимаю…..но все равно спасибо что потратили на меня время=) буду учить матчасть
Послал скетч по почте.
спасибо Вам огромное, все работает — я нарушил синтаксис программы, вот и ругалось!!!!!!!
а почему в 2 раза медленнее время отсчитывалось, не понимаю?
Здравствуйте ещё раз) Эдуард.
У меня просто нет слов, как Вы это делаете?
Чтобы мне было интересней изучать МК товарищ подкинул идею сделать ему таймер для игры в шахматы (убывающее время). Я там такого нагородил чтобы вычленить разряды минут секунд прочего, а тут просто переполнение и вывод на индикацию…
Восхищаюсь!
Не знаю читать дальше нет.
Чтобы совсем интерес не потерять на фоне того что всё без моего участия так хорошо придумано)
Спасибо, за комплимент.
ДОБРЫЙ ДЕНЬ!
КОПИРУЮ СКЕТЧ, ПРОВЕРЯЮ….
Arduino: 1.8.2 (Windows 7), Плата:»Arduino Nano, ATmega328″
fatal error: MsTimer2.h: No such file or directory
compilation terminated.
exit status 1
Ошибка компиляции для платы Arduino Nano.
КАК ЖИТЬ ДАЛЬШЕ?
Здравствуйте!
Проверьте, что установлена библиотека MsTimer2.h.
Убедитесь, что проект не сохранен в папке названной русскими буквами.
Здравствуйте, собрал секундомер по вашему уроку, спасибо вам огромное за ваши уроки. Тестировал на arduinoUNO все работало, а после решил перенести на arduinoMEGA 2560. И перестали работать кнопки. Борюсь, но никак не могу решить проблему. Плата рабочая, скетчи заливаются, кнопки через digitalRead функционируют. Но через библиотеку Button.h действий не выполняют. Подключал к ним светодиод кнопку замыкается никаких проблем. перепробовал все пины и ничего. Может вы сможете мне помочь понять суть проблемы и найти решение?
Здравствуйте!
На этой плате не работает библиотека MsTimer2. Надо использовать другую. Посмотрите в комментариях к уроку 10.
На платах Ардуино с частотой тактирования 16 мГц разрешение значения функции millis() составляет 4 мкс. Для плат с частотой 8 мГц – 8 мкс.
Может это о micros()?
Да, конечно. Я ошибся. Спасибо.
Здравствуйте. А возможно ли применение 6 секционного индикатора? 00.00.00 (минуты, секунды, сотые).
Еще несколько нюансов — После нажатия кнопки «старт» загорается красная лампочка и начинается обратный отсчет 5,4,3,2,1 и с нолем тухнет красная, загорается зеленая лампочка и стартует секундомер. Окончание работы секундомера по пересечению ик-створа. Время на индикаторе висит до нажатия на кнопку «сброс».
Такое возможно? Спасибо
Здравствуйте!
Все возможно. Но в данном уроке используется библиотека, которая поддерживает только 4 разряда LED индикатора.
Скетч работает, но если быстро тыкать кнопку СТАРТ/СТОП, зуммер начинает пищать и не останавливается пока несколько раз не потыкаешь все кнопки.
Если не трудно, скажите пожалуйста, что нужно изменить с скетче для индикаторов с общим катодом?
Здравствуйте!
При описании объекта Led4Digits первым аргументом указать тип индикатора 2.
Led4Digits disp(2, 5,4,3,2, 6,7,8,9,10,11,12,13);
В уроке 20 описаны варианты индикаторов.
Спасибо! Из всего, что я нашел в инете, Ваш прибор единственный, который нормально работает, а особенно удобно то, что всего при четырех разрядах обеспечивается такой широкий диапазон измерения за счет масштабирования младших разрядов.
Спасибо. Рад, что помог.
Эдуард! Скажите пожалуйста, точность счета зависит только от кварца? Наблюдается не сильное, но заметное отставание секундомера от реального.
В принципе да. А погрешность укладывается в пределы, которые я указываю в статье?
Можете попробовать заменить библиотеку прерывания по таймеру MsTimer2 на библиотеку TimerOne.h. О ней написано в уроке 29. В этой библиотеке период прерывания задается с дискретностью 1 мкс и вы можете подобрать время под ваш кварц с высокой точностью.
Можете открыть тему на форуме сайта, я помогу с программой.
Отставание 5 с. за 15 мин.
Спасибо за направление действий. Буду разбираться.
Огромное Спасибо, но есть одно НО. Хочу деткам для бассейна сделать большой секундомер, но там нужны ещё и минуты… Должно быть 6 цифр (сегментов). Подскажите пожалуйста, что для этого нужно.
Здравствуйте!
Устройство переключается на индикацию минут при времени более минуты. При этом показывает десятые доли секунд. Неужели такой точности недостаточно?
Если нет, то надо разрабатывать новое устройство. Библиотека Led4Digits поддерживает только 4 индикатора. Вам, наверное, надо использовать индикаторы больших размеров. Прежде всего решайте, какие индикаторы вы будете использовать, как их подключать к Ардуино.
Да, индикаторы должны быть больших размеров и их должно быть 6 штук. Первые два — минуты, вторые два — секунды, последние два — сотые… Как такое реализовать???
P.S. Индикаторы сам спаяю как надо.
Здравствуйте!
Спасибо за полезный урок.
А как изменить скетч, чтобы использовать светодиодный индикатор на на TM1637?
Здравствуйте. У меня проблема:когда нажимаю стоп, то на экране появляются все одинаковые цифры и на каждом сегменте горит точка. Подскажите пожалуйста в чем может быть проблема.
Здравствуйте!
Ошибка только когда удерживаете кнопку нажатой?
Может, тогда аппаратное замыкание вывода для кнопки. Проверьте вывод кнопки. Попробуйте подключите кнопку к другому выводу. Только в программе не забудьте изменить.
Нет, не только. После того как отпустил кнопку всё происходит также: цифры одинаковые, все точки горят
Здравствуйте!
А в остальном все работает правильно?
Здравствуйте. На табло, после остановки секундомера отображаются неправильно цифры (тоесть во всех 4х сегментах грамотно не отображается число (не хватает одной или несколько рисок)). Пересмотрел схему и нашел несколько недочетов: GND подсоединена была не на том выводе; AREF не был подключен. Поменял в программе входы и на схеме, но все оказалось без изменений. Скажите, пожалуйста от чего вы запитывали AREF?
AREF здесь совсем не причем. Программа не работает с АЦП. Я почти уверен, что у вас аппаратная ошибка — замыкание выводов управления индикаторами. Просмотрите и прозвоните все связи. Запустите мою программу из урока 20, которая отображают увеличивающееся число. Таким образом проверьте работу индикатора.
Здравствуйте, нашел ошибку: нужно было ИЗМЕНИТЬ ИНДИКАТОР в скетче и выбрать значения С ОБЩИМ КАТОДОМ, после этого все грамотно заработало. Благодарю Вас за помощь и отзывчивость
ДОБРЫЙ ДЕНЬ!!! Очень полезный Ваш урок, спасибо огромное за полезную информацию и грамотный урок. Подскажите пожалуйста, как сделать в вашем проекте, чтобы одна кнопка работала на Старт, а вторая на стоп?
Здравствуйте!
Откройте тему на форуме сайта. Например, в разделе «Проекты Ардуино». Напишите, что нужен аналог секундомера из урока 22, только c отдельными кнопками. Если можно, напишите, с какой целью будете использовать. Я подкорректирую скетч. В комментариях неудобно общаться, неудобно приводить скетчи.
Огромное спасибо за урок.
Простым языком, наглядно, по существу и доступно!
Спасибо, за отзыв.
Доброго времени суток!
Не получается подогнать этот скетч под дисплей ТМ1637
Как правильно написать программу в моём случае?
Общая ситуёвина такова — необходимо сделать секундомер так, чтобы он работал только лишь при зажатой кнопке, а при разжимании отчет времени становился на паузу.
Без всяких звуков там, лишь только отображение на дисплее.
Здравствуйте!
В комментариях к уроку я рассказывал, как сделать такой алгоритм.
Кстати, интересно, а для чего такой способ управления?
Такой способ управления необходим для создания игрового устройства для ролевых игр.
Такой способ управления необходим для создания игрового устройства для ролевых игр.
Как ни крути , не могу понять как вывести на этот дисплей счёт(
Есть библиотека для этого дисплея TM1637.h.
disp.displayInt(value); // вывести 1-4 значное число
disp.displayIntZero(value); // вывести 1-4 значное число с нулями СЛЕВА
Здравствуйте.
В принципе, интересный вариант, но довольно ресурсоемкий, в смысле цифровых портов ардуинки.
А чем плох вариант, когда программы-обработчики нажатия на кнопки вешать на irq (вх 2 и 3), а в качестве экрана использовать I2C ЖК дисплей 16×2 ?
Ведь важно точно засечь время, то есть моменты старта и финиша, а выводить на табло можно «лениво», особенно не парясь по поводу пауз между регенерациями дисплея.
Здравствуйте. Подскажите включение b dsrk.xtybt нагрузки по времени на часах ds1302.
и выключение —b dsrk.xtybt
здравствуйте,
вопрос,..при сборке схемы было перепроверено много раз её правильность, а так же пр компиляции и выгрузке тоже никаких проблем не было
в связи с этим вопрос- почему на индикаторе не отображается время..а только непонятные изображения по сегментам?
Здравствуйте!
Проверяйте схему.
Эдуард, подскажите ,а как работать с реальным временем на Ардуино? У нее же нет собственных часов, правильно? Только подключать модуль реального времени? А может есть еще какие-то хитрые способы?
Здравствуйте!
Есть основной кварцевый генератор. С помощью него и отсчитывается время. Другие способы трудно придумать.
Добрый вечер. А возможно в такой программе запустить 4 секундомера одновременно?
Здравствуйте!
Что значит в такой программе?
Возможности простых плат Ардуино на ATmega328 это позволяют.
На 16MHz платах Ардуино (Duemilanove и Nano) функция micros() имеет разрешение 4 микросекунды (возвращаемое значение всегда кратно 4). На 8MHz платах (Arduino Lilypad) разрешение функции 8 микросекунд. Но и на других моделях аналогичная ситуация?
значит if (micros()%1000=0) работать не будет, а при
if (micros()-lastmicros>1000) {
lastmicros=micros();}
будет работать при условии unsigned long lastmicros;
но при переполнении не возникнет ли ошибка (через 70 минут)?
Здравтвуйте! Переделал ваш скетч для таймера обратного отсчета. Работает, но как выяснилось иногда время останавливается на различных показаниях, например, 4:00, 6:00, т.е. значение минут может быть разным,а секунды и десятки секунд всегда при этом по нулям. В чем моя ошибка? Кусочек кода ниже. Спасибо заранее
if ( c==1 ) { // СТОП
// if ( (minTime == 0) && (decMinTime == 0) && (msTime 0) && (minTime > 0) ) {
// милисекунды дошли до 0
msTime = 60000;
minTime —;// -1 к единицам минут
}
if ( (minTime == 0) && (decMinTime > 0) && ((msTime/100)==0)) {
msTime = 60000;decMinTime —; minTime = 9;
}
if ( (minTime > 0) && (decMinTime == 0) && ((msTime/100)==0)) {
msTime = 60000; minTime—;
}
if ( (minTime == 0) && (decMinTime == 0) && (msTime/100==0)){
if (c == 0){soundCount=9;c = 1;}
msTime=0;
}
else {
curentTime = millis(); // чтение текущего времени
msTime -= (curentTime — prevTime); // уменьшение времени по милисекундам
}
prevTime = curentTime; // перегрузка предыдущего времени
}
Извиняюсь, не полностью вставил код
if ( c==1 ) { // СТОП
prevTime = millis()*2.175;//предыдущее значене времени
}
else { // ПУСК
}
if ( ((msTime/100)==0) && (decMinTime > 0) && (minTime > 0) ) {
// милисекунды дошли до 0
msTime = 60000;
minTime —;// -1 к единицам минут
}
if ( (minTime == 0) && (decMinTime > 0) && ((msTime)==0)) {
msTime = 60000;decMinTime —; minTime = 9;
}
if ( (minTime > 0) && (decMinTime == 0) && ((msTime)==0)) {
msTime = 60000; minTime—;
}
if ( (minTime == 0) && (decMinTime == 0) && (msTime==0)){
if (c == 0){soundCount=9;c = 1;}
msTime=0;
}
else {
curentTime = millis(); // чтение текущего времени
msTime -= (curentTime — prevTime); // уменьшение времени по милисекундам
}
prevTime = curentTime; // перегрузка предыдущего времени
}
Эдуард добрый день! Купил неоригинальный Arduino 328P AU1643. Пробовал залить ваш скетч, но не получилось.
Думаю, что дело в драйвере (устанавливал вот этот — CH341SER).
Сейчас в разделе Computer management—-Ports (Com,Lpt)—- Serial port, Multifunctional cable (COM9). Контроллер не определяется…
Вот текст ошибки:
Arduino: 1.8.9 (Windows 7), Board: «Arduino/Genuino Uno»
Sketch uses 11262 bytes (34%) of program storage space. Maximum is 32256 bytes.
Global variables use 198 bytes (9%) of dynamic memory, leaving 1850 bytes for local variables. Maximum is 2048 bytes.
avrdude: stk500_recv(): programmer is not responding
avrdude: stk500_getsync() attempt 1 of 10: not in sync: resp=0xc5
avrdude: stk500_recv(): programmer is not responding
avrdude: stk500_getsync() attempt 2 of 10: not in sync: resp=0xc5
avrdude: stk500_recv(): programmer is not responding
avrdude: stk500_getsync() attempt 3 of 10: not in sync: resp=0xc5
avrdude: stk500_recv(): programmer is not responding
avrdude: stk500_getsync() attempt 4 of 10: not in sync: resp=0xc5
avrdude: stk500_recv(): programmer is not responding
avrdude: stk500_getsync() attempt 5 of 10: not in sync: resp=0xc5
avrdude: stk500_recv(): programmer is not responding
avrdude: stk500_getsync() attempt 6 of 10: not in sync: resp=0xc5
avrdude: stk500_recv(): programmer is not responding
avrdude: stk500_getsync() attempt 7 of 10: not in sync: resp=0xc5
avrdude: stk500_recv(): programmer is not responding
avrdude: stk500_getsync() attempt 8 of 10: not in sync: resp=0xc5
avrdude: stk500_recv(): programmer is not responding
avrdude: stk500_getsync() attempt 9 of 10: not in sync: resp=0xc5
avrdude: stk500_recv(): programmer is not responding
avrdude: stk500_getsync() attempt 10 of 10: not in sync: resp=0xc5
Problem uploading to board. See http://www.arduino.cc/en/Guide/Troubleshooting#upload for suggestions.
Что можете посоветовать?
Здравствуйте!
Возможно у вас в плате бутлоадер стерт.
Еще можно набрать в поисковой строке «ардуино avrdude: stk500_recv(): programmer is not responding» и поискать советы в интернете.
Здравствуйте! Подключил всё, но дисплей моргает всеми сегментами и не выдает четкие цифры. пробовал менять сопротивления меньше килоома, но результата нет. возможно это исправить номиналом сопротивлений?
Здравствуйте!
У вас индикатор с общим катодом, а у меня в уроке с общим анодом. Посмотрите уроки 19 и 20. Надо проверить в конструкторе соответствие выводов и указать первым аргументом тип индикатора — 2.
Led4Digits disp(2, 5,4,3,2, 6,7,8,9,10,11,12,13);
означает: тип индикатора 2; выводы разрядов 5,4,3,2; выводы сегментов 6,7,8,9,10,11,12,13.
Добрый день!
Я заметил опечатку в 25 строке: «MsTimer2::set(2, timerInterRupt)»
опечатка timerInterRupt вместо timerInterupt.
прошу помощи, ни как не могу скомпилировать готовый код этого урока. Вот текст который мне выдает:
»
C:\Users\1\Desktop\Documents\Arduino\sketch_apr18a\sketch_apr18a.ino: In function ‘void setup()’:
sketch_apr18a:25:20: error: ‘timerInterupt’ was not declared in this scope
MsTimer2::set(2, timerInterupt); // задаем период прерывания по таймеру 2 мс
^~~~~~~~~~~~~
C:\Users\1\Desktop\Documents\Arduino\sketch_apr18a\sketch_apr18a.ino:25:20: note: suggested alternative: ‘attachInterrupt’
MsTimer2::set(2, timerInterupt); // задаем период прерывания по таймеру 2 мс
^~~~~~~~~~~~~
attachInterrupt
C:\Users\1\Desktop\Documents\Arduino\sketch_apr18a\sketch_apr18a.ino: In function ‘void loop()’:
sketch_apr18a:120:24: error: a function-definition is not allowed here before ‘{‘ token
void timerInterrupt() {
^
exit status 1
‘timerInterupt’ was not declared in this scope»
Здравствуйте!
Почему-то у вас в объявлении обработчика прерываний указано timerInterupt, а сам обработчик timerInterrupt. На эту ошибку указывает компилятор.
Все же, мГц — это миллиГерцы, а МГц — это МегаГерцы.
В технических текстах такая опечатка нежелательна 🙂
Посмотрю. Спасибо.
Спасибо за чудесные уроки.
Хочу сделать маме сенсорный секундомер. Но все мои попытки разбиваются о неизвестный «подводный камень» — а именно, отказываются «дружить» одновременно три сущности: дисплей TM1637, пассивный зуммер, сенсорный датчик. До тех пор, пока я не вешаю прерывание от последнего, все хорошо работает. Как только прерывание инициируется, МК уходит в зависание, не реагирует, а зуммер пищит постоянно — вместо того, чтобы раз коротко «пикнуть» в момент прикасания пальцем к датчику…
Какие только я библиотеки не перебрал — все безполезно, складывается впечатление, что невозможно построить устройство с перечисленными компонентами, но это же очевидный бред!!!
В последней попытке реализации используются библиотеки FlexiTimer2.h, TM1637Display.h и альтернативная функция «FreeTone()» для зуммера без использования таймеров. МК — ATmega328P.
Решение вопроса выходит за рамки моих познаний, я весь измучился на ровном месте, а мама замучилась считать пульс по минутному периоду работы подсветки телефона… Помогите, плиз, если не сложно…
Здравствуйте!
А почему нельзя подключить сенсорный датчик вместо кнопки и опрашивать его в цикле, как это сделано в уроке?
Здравствуйте, как из этой программы сделать программу для того чтобы был миллисекундомер?
Здравствуйте!
В блоке «отображение времени -> меньше минуты» убрать деление на 10.
disp.print(msTime, 4, 0); // вывод четырех разрядов миллисекунд
Тогда, если значение времени меньше минуты, то будут отображаться миллисекунды.